blackcj.com » AIR http://www.blackcj.com/blog Cutting edge development with Adobe Flex, ActionScript and AIR Thu, 15 Dec 2011 01:01:57 +0000 en hourly 1 http://wordpress.org/?v=3.3 Publishing Apps to iOS, Android and BlackBerry with AIR http://www.blackcj.com/blog/2011/02/02/publishing-apps-to-ios-android-and-blackberry-with-air/ http://www.blackcj.com/blog/2011/02/02/publishing-apps-to-ios-android-and-blackberry-with-air/#comments Wed, 02 Feb 2011 20:44:19 +0000 Chris Black http://www.blackcj.com/blog/?p=942 Using Flash Builder Burrito and the Flash IDE you can export your ActionScript projects to three mobile platforms without any change in code! Let's take a look at how to make this possible. Before we get started, here is a video with one of my demo apps running on all three devices:

Multi-screen:
The variety of screen resolutions and DPIs can be the hardest part of building a mobile app. When building an AIR app for mobile devices you have two important properties Capabilities.screenResolutionX(Y) and Capabilities.screenDPI. Using stage.stageWidth on mobile devices does not work the way you would expect it to. If you set up your application in Flash to have a width of 480 and a height of 800, the stageWidth and stageHeight will return these numbers even if the screen is smaller. Another thing to note is that the iOS packager currently targets 320x480 even though many of the iOS devices run 640x960. We'll account for that by adding a screenResolution check.

In my application when a device has lower than 400 pixels in width I drop down the paint brush width. When the device has higher than 400 pixels I increase the size of the menu accordingly. A better approach would be to use the Capabilities.screenDPI for this calculation rather than just the screenResolution. All of your view components should be able to render at different DPIs and resolutions. When you know this from the start it is easy to build into the code. Here is an example:

PLAIN TEXT
Actionscript:
  1. if(Capabilities.screenResolutionX <400){
  2.     _canvas = new SimplePaint(Capabilities.screenResolutionX, Capabilities.screenResolutionY-85);
  3.     _canvas.ratio = 0.66;
  4. }else{
  5.     _canvas = new SimplePaint(Capabilities.screenResolutionX, Capabilities.screenResolutionY-125);
  6.     _menuBar.scaleX = _menuBar.scaleY = 1.5;
  7. }

Notice how we are changing the size ratio of the brushes for smaller screens with a lower DPI. For larger screens we are increasing the size of the menu. This makes the application appear the same to the end user even when the app is running at 480x800 on the Android and 320x480 on the iOS! This could be improved to use the actual DPI value but the basic idea is there.

Multi-touch
This is the easy part. Use the Multitouch.maxTouchPoints to determine if the device supports touch. If it does than add touch listeners, if the device has 0 touch points add mouse event listeners. Don't be that person that only codes for one device. With only a few extra lines of code you app will work on desktop and mobile. This also makes debugging much easier!

PLAIN TEXT
Actionscript:
  1. if(Multitouch.maxTouchPoints> 0){
  2.     Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;
  3.     _canvas.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
  4.     _canvas.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove);
  5.     _canvas.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);
  6. }else{
  7.     _canvas.addEventListener(MouseEvent.MOUSE_DOWN, onMouseBegin);
  8.     _canvas.addEventListener(MouseEvent.MOUSE_MOVE, onMyMouseMove);
  9.     _canvas.addEventListener(MouseEvent.MOUSE_UP, onMouseEnd);
  10. }

Wasn't that easy? One thing to note is that TOUCH_END was not always dispatched, especially when you start using 3+ touch points. To work around this add a timer into your class that checks to see if a TOUCH_MOVE event has been called. The TOUCH_MOVE event is dispatched even when the user has stopped moving and only stops when the touch has ended. As a backup, check every half a second or so to make sure the specific touch point id is still moving.

Setup:
To setup your workspace to export to all three platforms you'll need to create a ActionScript only Mobile project in Flash Builder Burrito. Create an FLA in the source folder that uses the runnable AS file as its base. Create your assets in the FLA file, export them into a SWC to be used for FB and mark them as run time compiled so they work with the Flash IDE. From here you can export to all three devices without changing any files. Life is good :)

Conclusion:
In just 17 lines of code and a little setup we've got our multi-screen, multi-touch application ready to go! Make sure to add your event listeners for Android to close the app when the user hits back or home. This entire painting application is less than 400 lines of code (~4KB compiled), was built from scratch in less than 12 hours and is easily maintainable across multiple platforms. Performance is great and native APIs are easy to use. My only complaints are that the file size for the iOS is rather large and the iOS exporter doesn't support the Camera API yet. Outside of that, this is the best way to build cross platform apps.

Wet Paint on the Web:

Wet Paint Flash application.

Get Adobe Flash player

Porting to the web required changing 3 lines of code. To get these source files running on mobile devices change the _webMode value to false and remove the width / height from the SWF declaration. I also had to comment out the cacheAsBitmapMatrix to get it running on the web. Still very easy to convert!

Source files.

Enjoy!

]]> http://www.blackcj.com/blog/2011/02/02/publishing-apps-to-ios-android-and-blackberry-with-air/feed/ 5 Six Months on AIR http://www.blackcj.com/blog/2009/06/05/six-months-on-air/ http://www.blackcj.com/blog/2009/06/05/six-months-on-air/#comments Fri, 05 Jun 2009 17:19:38 +0000 Chris Black http://www.blackcj.com/blog/?p=355 Attention AIR developers: Are you interested in learning about caching images in binary format, SQLite database migration, re-using existing view components, memory fragmentation and general tips / tricks about developing your application using Adobe AIR? If you answered YES than you should attend Minh Vu and Chris Black's session at Flashbelt on June 8th at 1:30PM. We're going to have a killer presentation for everyone interested in developing Adobe AIR desktop applications.

Can't attend Flashbelt?
I would highly recommend attending Flashbelt. Networking opportunities, great presentations and lots of fun! OK, if you absolutely can go than check out our presentation below.

Who should attend?
Developers that are currently developing AIR applications or are interested in doing AIR development in the future. Project managers would also benefit from knowing the decisions that go into creating large scale applications. How about designers? This presentation is geared towards the development side of AIR but designers are welcome.

Six Months on AIR: A Look at Skimmer

BulkLoader with Binary data format:
link

About the presenters:
Chris Black is a Senior Developer at Sierra Bravo who focuses on ActionScript development with Adobe Flex and AIR, and is interested in integrating social networking APIs into Rich Internet Applications. He covers these topics as well as sharing solutions to the problems he encounters when working with Flex and AIR on his blog, blackcj.com. Chris has a degree in Computer Science from the University of Wisconsin - Eau Claire, and when he's away from the computer he enjoys rock climbing, backpacking, and tennis.

Minh Vu is a Developer at Sierra Bravo who works on interactive development with ActionScript, JavaScript, and iPhone. He has a strong interest in applying Model Driven Development to Flash or AIR applications. Minh studied at the University of Minnesota Duluth where he got his degree is in Information System & Technology. In his spare time he enjoys disc golfing, snowboarding and ultimate frisbee.

]]> http://www.blackcj.com/blog/2009/06/05/six-months-on-air/feed/ 3 Skimmer http://www.blackcj.com/blog/2009/03/24/skimmer/ http://www.blackcj.com/blog/2009/03/24/skimmer/#comments Tue, 24 Mar 2009 06:51:25 +0000 Chris Black http://www.blackcj.com/blog/?p=275 "A lifestreaming thing that lets you see it all in one place"

Skimmer. The next Adobe AIR app and the hard work of many individuals over the past 6 months. It has been amazing to see this application turn from design into reality. This is a summary of the technologies used and some of the lessons learned throughout the development of Skimmer:

Skimmer

Skimmer

The first decision was easy. Use an MVC framework, more specifically PureMVC. This application was estimated in the thousands and having a backbone was very important. We spent the extra time upfront developing a solid structure which ended up helping out immensely when it came to bug fix and adding new features. Creating new views became a snap when the data providers that accessed third party API's were completed.

The second major decision was to use a SQLite database to store content locally. This allowed for fast filtering of data and pre-processing of information. It also greatly improved the load time of the application since we only needed to gather new information.

Thirdly, we decided to use image caching for all of the commonly used images to improve load times. This increased the application start up and allows for fluid transitions between images in slide shows. By extending a bulk loader class Skimmer is able to first check the local cache before making any requests to the internet for images.

One of the major challenge was working with the third party API's. The API's for Flickr, YouTube, Twitter, TwitPic, Facebook and Blogger had varying levels of documentation and support. Flickr had the most feature rich API while Facebook had the most difficult API to work with. Many of them had third party AS3 libraries to use for interfacing with the service that we used as a base.

Another challenge was in skinning the flex components. The application was not designed to look like an AIR application, which is a good thing :) This, however, did create some interesting problems along the way. We used a combination of CSS, class inheritance, overrode drawing methods, and even created some custom flex components.

You can download skimmer here:
http://www.fallon.com/skimmer

A shout out to everyone that made this happen:
AL KELLY, BRENDA FOGG, CHRIS WIGGINS, DAVID SCHWEN. EXTENDED TEAM: ANDY GUGEL, SIERRA BRAVO, ANDREW WATSON, BEN DOLMAR, BLAGVOST DACHEV, CLAYTON SMITH, JON REXEISEN, KARSTEN LUNDQUIST, KONR NESS, KRIS SZAFRANSKI, MARK SEEMANN, MANISH SHRESTHA, MATT TONAK, MICHAEL WOODS, MINH VU, ROBB THOMAS, THOMAS O'NEILL.

Feel free to post any comments or questions you have about Skimmer.

http://mashable.com/2009/03/24/skimmer/

]]> http://www.blackcj.com/blog/2009/03/24/skimmer/feed/ 18 Display TwitPic Images in Flex & AIR http://www.blackcj.com/blog/2009/02/23/display-twitpic-images-in-air-or-anywhere/ http://www.blackcj.com/blog/2009/02/23/display-twitpic-images-in-air-or-anywhere/#comments Tue, 24 Feb 2009 00:50:37 +0000 Chris Black http://www.blackcj.com/blog/?p=230 Problem:
The TwitPic API does not currently support outgoing requests and the image source from amazon aws contains an AWS AccessKeyId, expiration time stamp, and signature. This would normally require a regular expression to rip the source JPG path out of the HTML. Ripping the source out of the HTML is a bit of a pain and is not a long term solution. It is possible to use the following shortened url to gain access to the full image path using the TwitPic image id.

Solution:
Use this url to gain access to the full http://twitpic.com/show/full/s0z4.jpg and thumbnail http://twitpic.com/show/thumb/s0z4.jpg images (replace the s0z4 with your image id). Notice that this shortened path returns the longer url that would normally have to be ripped out of the HTML to gain access to the image.

PLAIN TEXT
HTML:
  1. <mx:HTTPService
  2.     id="rssParse"
  3.     url="php/twitpic.php"
  4.     result="processResult(event)"
  5.     resultFormat="e4x" />

PLAIN TEXT
PHP:
  1. <?php
  2.   $twitter_feed = 'http://twitpic.com/photos/chrisjblack/feed.rss';
  3.   $rawfeed = @file_get_contents($twitter_feed);
  4.   print $rawfeed; 
  5. ?>

PLAIN TEXT
Actionscript:
  1. import mx.collections.ArrayCollection;
  2. import mx.rpc.events.ResultEvent;
  3.  
  4. [Bindable]
  5. private var _rssResults:ArrayCollection;
  6.  
  7. // Define and use atom namespace.
  8. private namespace atom = "http://www.w3.org/2005/Atom";
  9. use namespace atom;
  10.  
  11. private function processResult(event:ResultEvent):void
  12. {
  13.     var xmlList:XMLList = event.result.channel.item as XMLList;
  14.     for each(var item:XML in xmlList){
  15.         // Formatt the date
  16.         var myDate:String = item.pubDate;
  17.         myDate = myDate.slice(0,22);
  18.        
  19.         // Pull the image id out of the link url
  20.         var imageId:String = item.link;
  21.         imageId = imageId.replace("http://twitpic.com/", "");
  22.        
  23.         // Push the results into our data array
  24.         _rssResults.addItem({title: item.title, date: myDate, id: imageId});
  25.     }
  26. }
  27.  
  28. private function init():void
  29. {
  30.     _rssResults = new ArrayCollection();
  31.     rssParse.send();
  32. }

PLAIN TEXT
HTML:
  1. <mx:VBox width="900" height="500" horizontalAlign="center"> 
  2.     <mx:Label styleName="subTitleText" text="Twitter Feed:" fontWeight="bold" fontSize="16"/>
  3.     <mx:VBox height="450" width="800" verticalScrollPolicy="auto" horizontalScrollPolicy="off" horizontalAlign="center">
  4.         <mx:Repeater id="twitter" dataProvider="{_rssResults}">
  5.             <mx:Text textAlign="center" width="300" text="{twitter.currentItem.date}"/>
  6.             <mx:Text textAlign="center" width="300" text="{twitter.currentItem.title}"/>
  7.             <mx:Image source="http://twitpic.com/show/thumb/{twitter.currentItem.id}.jpg" />
  8.             <mx:Image source="http://twitpic.com/show/full/{twitter.currentItem.id}.jpg" />
  9.         </mx:Repeater>     
  10.     </mx:VBox> 
  11. </mx:VBox>

This allows for Adobe AIR applications to post to (Post to TwitPic from Adobe AIR) and retrieve images from TwitPic.

View Sample / Source Files

Links:
TwitPic Previewer

]]> http://www.blackcj.com/blog/2009/02/23/display-twitpic-images-in-air-or-anywhere/feed/ 2 Validate Twitter Credentials in AIR http://www.blackcj.com/blog/2008/12/21/validate-twitter-credentials-in-air/ http://www.blackcj.com/blog/2008/12/21/validate-twitter-credentials-in-air/#comments Sun, 21 Dec 2008 22:21:42 +0000 Chris Black http://www.blackcj.com/blog/?p=131 Problem:
Your AIR application needs to validate the username / password and handle failure gracefully within the application. If the user enters the wrong information you do not want them to be prompted with a windows prompt asking them to enter their Twitter username / password. If the application needs to hold on to the credentials for any reason the windows authentication to the API will break the AIR application.

"The server twitter.com at Twitter API requires a username and password."

Windows Authentication Pop-up Message.

Windows Authentication Pop up message.

Solution:
The URLRequest object has a property called 'authenticate' that must be set to false.

PLAIN TEXT
Actionscript:
  1. /**
  2. *
  3. * Setting result.authenticate to false prevents the operating system from
  4. * taking over and prompting the user to authenticate.  It allows the AIR
  5. * application to take the correct action.
  6. *
  7. */  
  8. private function twitterRequest (url : String):URLRequest
  9. {
  10.     var result:URLRequest = new URLRequest (url);
  11.     if (this.authorizationHeader){
  12.         result.authenticate = false;  // <--------- Most Important Line of Code!!!!
  13.         result.requestHeaders = [this.authorizationHeader]; 
  14.     }
  15.     return result;
  16. }

Most of the code from the example attached below is from the Google code repository:

http://code.google.com/p/twitterscript/

Here are the source files to an example AIR application that uses actionscript to verify Twitter credentials without prompting a windows box on failure:

Source Files

I would like to give credit to Clayton (file_cabinet) for coming up with the solution to this problem. Thanks Clayton!

]]> http://www.blackcj.com/blog/2008/12/21/validate-twitter-credentials-in-air/feed/ 7 Post to TwitPic from Adobe AIR http://www.blackcj.com/blog/2008/11/20/post-to-twitpic-from-adobe-air/ http://www.blackcj.com/blog/2008/11/20/post-to-twitpic-from-adobe-air/#comments Fri, 21 Nov 2008 00:19:44 +0000 Chris Black http://www.blackcj.com/blog/?p=103 TwitPic is a service that lets you share photos on Twitter by generating a tiny url to the image being uploaded. The flash.filesystem.File class allows Adobe AIR to post an image to TwitPic. By specifying the username, password and posting method it is possible to submit a query to the TwitPic API.

PLAIN TEXT
Actionscript:
  1. package com.cb.twitpic
  2. {
  3.     import flash.events.DataEvent;
  4.     import flash.events.Event;
  5.     import flash.filesystem.File;
  6.     import flash.net.FileFilter;
  7.     import flash.net.URLRequest;
  8.     import flash.net.URLRequestMethod;
  9.     import flash.net.URLVariables;
  10.    
  11.     public class TwitPic
  12.     {
  13.         private var _file:File;
  14.        
  15.         public function TwitPic()
  16.         {
  17.             _file = new File();
  18.             _file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
  19.             browse();
  20.         }
  21.         private function browse():void {
  22.             _file.addEventListener(Event.SELECT, fileSelected);
  23.             _file.browse( new Array( new FileFilter( "Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png" ) ) );
  24.         }
  25.        
  26.         private function fileSelected(event:Event):void {
  27.             var urlRequest:URLRequest = new URLRequest("http://twitpic.com/api/upload");
  28.            
  29.             // The API requires the request be sent via POST
  30.             urlRequest.method = URLRequestMethod.POST;
  31.            
  32.             // Enter a valid Twitter username / password combination
  33.             var urlVars:URLVariables = new URLVariables();
  34.             urlVars.username = TWITTER_USERNAME;
  35.             urlVars.password = TWITTER_PASSWORD;
  36.             urlRequest.data = urlVars;
  37.            
  38.             // The API requires the file be labeled as 'media'
  39.             _file.upload(urlRequest, 'media');
  40.         }
  41.        
  42.         private function uploadCompleteDataHandler(event:DataEvent):void
  43.         {
  44.             var resultXML:XML = new XML(event.text);
  45.            
  46.             // Trace the path to the resulting image tiny url (mediaurl)
  47.             trace(resultXML.child("mediaurl")[0]);
  48.         }
  49.     }
  50. }

This can be used within an AIR application by importing TwitPic and initializing the class.

Sample Code
http://www.blackcj.com/PostTwitPicFromAIR.zip

]]> http://www.blackcj.com/blog/2008/11/20/post-to-twitpic-from-adobe-air/feed/ 17 SQLite in AIR http://www.blackcj.com/blog/2008/10/20/sqlite-in-air/ http://www.blackcj.com/blog/2008/10/20/sqlite-in-air/#comments Mon, 20 Oct 2008 20:36:00 +0000 Chris Black http://www.blackcj.com/blog/?p=55 When doing research on integrating a SQLite Database into AIR I came across the following useful resources:

Learn what SQLite is About:
Introduction to the SQLite Database - David Tucker

Getting Started:
Introduction to SQLite in Adobe AIR

Tool for Creating and Modifying SQLite Databases:
SQLite Firefox Extension

By using a SQLite database it will be easy to filter data returned by services based on tags. A demo application that uses SQLite will be coming soon. Feel free to comment with any additional resources or cool demo applications that use SQLite.

]]> http://www.blackcj.com/blog/2008/10/20/sqlite-in-air/feed/ 0 YouTube in AIR http://www.blackcj.com/blog/2008/10/14/youtube-in-air/ http://www.blackcj.com/blog/2008/10/14/youtube-in-air/#comments Tue, 14 Oct 2008 22:32:46 +0000 Chris Black http://www.blackcj.com/blog/?p=32 The YouTube video player is currently written in ActionScript 2.0 and integrating it into an AIR application requires a few additional steps. There are many solutions available that reverse engineer the URL to get access to the source video FLV, however, this breaks the terms of service and is not officially supported by YouTube or the API.

By taking advantage of the HTMLLoader class we are able to load the YouTube Chromeless video player into AIR without breaking the terms of service. It essentially loads up a web page within the AIR application and uses JavaScript to control the video.

Lets start by creating the JavaScript / HTML portion of the application that the HTMLLoader will consume. Resources for this can be found here; YouTube Chromeless Player Example page.

Simplified JavaScript functions for this example (includes Play, Pause and Load):

PLAIN TEXT
JavaScript:
  1. <script src="js/swfobject.js" type="text/javascript" />
  2. <script type="text/javascript">
  3.  
  4.     function onYouTubePlayerReady(playerId) {
  5.       ytplayer = document.getElementById("myytplayer");
  6.     }
  7.  
  8.     // functions for the api calls
  9.     function loadNewVideo(id, startSeconds) {
  10.       if (ytplayer) {
  11.         ytplayer.loadVideoById(id, startSeconds);
  12.       }
  13.     }
  14.  
  15.     function play() {
  16.       if (ytplayer) {
  17.         ytplayer.playVideo();
  18.       }
  19.     }
  20.  
  21.     function pause() {
  22.       if (ytplayer) {
  23.         ytplayer.pauseVideo();
  24.       }
  25.     }
  26.    
  27. </script>

Next we will use the SWFObject to load in the YouTube Chromeless video player. Notice the use of wmode: "opaque" in this example. Without this you will not be able to place any display objects above your videos.

PLAIN TEXT
JavaScript:
  1. <script type="text/javascript">
  2.  
  3.       // allowScriptAccess must be set to allow the Javascript from one
  4.       // domain to access the swf on the youtube domain
  5.       var params = { allowScriptAccess: "always", bgcolor: "#cccccc", wmode: "opaque" };
  6.       // this sets the id of the object or embed tag to 'myytplayer'.
  7.       // You then use this id to access the swf and make calls to the player's API
  8.       var atts = { id: "myytplayer" };
  9.       swfobject.embedSWF("http://www.youtube.com/apiplayer?enablejsapi=1&playerapiid=ytplayer",
  10.                          "ytapiplayer", "400", "300", "8", null, null, params, atts);
  11.  
  12. </script>

ActionScript Used to Load and Control the Video:

PLAIN TEXT
Actionscript:
  1. package com.sb.util
  2. {
  3.     import flash.display.Sprite;
  4.     import flash.events.Event;
  5.     import flash.html.HTMLLoader;
  6.     import flash.net.URLRequest;
  7.    
  8.     public class JSVideoPlayer extends Sprite
  9.     {
  10.    
  11.         private var _html:HTMLLoader;
  12.         private var _ready:Boolean = false;
  13.        
  14.         public function JSVideoPlayer()
  15.         {
  16.             _html = new HTMLLoader();
  17.             _html.paintsDefaultBackground = false;
  18.             _html.width = 400;
  19.             _html.height = 300;
  20.             _html.addEventListener(Event.COMPLETE,
  21.                               onComplete);
  22.            
  23.             loadHTMLcontent()
  24.  
  25.             this.addChild( _html );
  26.         }
  27.         public function loadNewVideo(videoID:String):void
  28.         {
  29.             if(_ready){
  30.                 _html.window.loadNewVideo(videoID);
  31.             }
  32.         }
  33.        
  34.         public function playVideo():void
  35.         {
  36.             if(_ready){
  37.                 _html.window.play();
  38.             }
  39.         }
  40.  
  41.         public function pauseVideo():void
  42.         {
  43.             if(_ready){
  44.                 _html.window.pause();
  45.             }
  46.         }
  47.        
  48.         private function onComplete (e:Event):void
  49.         {
  50.             _ready = true;
  51.         }
  52.        
  53.         public function loadHTMLcontent():void
  54.         {
  55.             _html.load(new URLRequest('test.html'));
  56.         }
  57.    
  58.     }
  59. }

YouTube in AIR

YouTube in AIR

One of the limitations of using the HTMLLoader class is the inability to set the opacity of the video. For example you if wanted to fade the video out you would have to capture the current state of the video and replace it with a bitmap image that would then be faded out (download the zip file to see an example of this).

Source Files (ZIP)

Enjoy!

Sources:

  • Creating JavaScript functions within an ActionScript class in AIR, Marco Casario link
  • YouTube Chromeless Player Example page google.api

PS: This example is only for AIR and may not work for Flex applications deployed on web sites. Please visit 'YouTube in Flex applications' (On The Other Hand) for an example of how to do this in Flex.

]]> http://www.blackcj.com/blog/2008/10/14/youtube-in-air/feed/ 2 Mash up applications with Adobe AIR http://www.blackcj.com/blog/2008/10/14/developing-mash-up-applications-with-adobe-air/ http://www.blackcj.com/blog/2008/10/14/developing-mash-up-applications-with-adobe-air/#comments Tue, 14 Oct 2008 15:21:38 +0000 Chris Black http://www.blackcj.com/blog/?p=29 When doing some research on integrating YouTube videos into Adobe AIR applications I came across this presentation. Marco Casario talks about the design patterns and technologies that can be used to aggregate social media networks in AIR. The Adobe AIR Cookbook will be out in November 2008 and will have more information on these topics.

Developing Mash up applications with Adobe AIR
View SlideShare presentation or Upload your own. (tags: ria flex)

http://casario.blogs.com/mmworld/2008/10/developing-mash.html

I will be posting soon with an example Flex and AIR application that can play YouTube videos (without breaking the terms of service). Many people today are reconstructing the URL to the source FLV which is against the terms of service. Between this presentation and another blog entry about YouTube in Flex applications (On The Other Hand) I should be able to post an example for both.

]]> http://www.blackcj.com/blog/2008/10/14/developing-mash-up-applications-with-adobe-air/feed/ 0